3 votos

Cómo guardar los mensajes enviados en la misma carpeta que el mensaje que se respondió?

Una de mis características favoritas de la espalda cuando he usado Outlook fue la opción para guardar los correos electrónicos enviados en la misma carpeta que el mensaje que se respondió. Por ejemplo, si yo me había mudado a un mensaje a Una carpeta y fue responder a eso, mi respuesta fue guardado en Una, no se Envía. (Si he respondido a un mensaje en mi Bandeja de entrada, mi respuesta fue a la predeterminada de la carpeta de elementos Enviados.)

Esto hace que sea muy fácil para ver toda la conversación, cuando volví a ella más tarde. Este flujo de trabajo es un gran ahorro de tiempo para mí y es la única cosa que echo de menos desde Outlook. Ahora, puedo mover manualmente los mensajes enviados en la carpeta con los mensajes relacionados con que es tedioso. Es allí una manera de recrear esta característica de Outlook con el Correo de Mac? (Estoy usando el Correo de Mac 6.2 en OSX 10.8.2).

2voto

Phill Puntos 126

El correo puede ser extendido para imitar bastante de cerca la función de mencionar que desde Outlook.

OS X incluye una característica denominada servicios que pueden ser usados para extender la funcionalidad de una aplicación (consulte la http://www.macosxautomation.com/services/learn/index.html para obtener más información).

Voy a utilizar Automator y AppleScript para crear un servicio que mueve los mensajes enviados en la carpeta con el mensaje que se respondió, y luego asignar la respuesta estándar método abreviado de teclado (R) para el servicio:

  • Cierre De Correo.

  • Abrir Automator en la carpeta Applications y elegir el Servicio:

enter image description here

  • Seleccione Utilidades en virtud de la Biblioteca y arrastre Ejecutar AppleScript para el vacío panel de la derecha:

enter image description here

  • Configurar el servicio para recibir ninguna entrada en el Correo:

enter image description here

  • Reemplace el contenido de la Ejecutar AppleScript acción con:

    on run {input, parameters}
    
    tell application "Mail"
        try
            (* Get selected messages or exit *)
            set messageSelection to selection
            set selectedMessage to item 1 of messageSelection
            set replyMessage to reply selectedMessage opening window yes
            set messageID to message id of selectedMessage
            set currentMailbox to mailbox of selectedMessage
        on error
            return
        end try
        repeat
            (* Wait until reply message is sent *)
            delay 2
            try
                if replyMessage is not visible then exit repeat
            on error
                exit repeat
            end try
        end repeat
        synchronize with (account of currentMailbox)
        (* Wait while reply message is being sent *)
        delay 10
        (* Loop over all sent messages *)
        set sentMailbox to sent mailbox of application "Mail"
        set allSentMessages to messages of sentMailbox
        repeat with sentMessage in allSentMessages
            if source of sentMessage contains messageID then
                set mailbox of sentMessage to currentMailbox
                return
            end if
        end repeat
    end tell
    
    return input
    end run
    
    • Guardar con un nombre descriptivo, como Respuesta y Mover Mensaje Enviado a la Carpeta Actual. El servicio será guardado en ~/Library/Services/. Esto es lo que el servicio se ve así:

enter image description here

  • Abra Preferencias del Sistema, seleccione el Teclado del panel de preferencias y, a continuación, los métodos Abreviados de Teclado de la ficha.

  • Seleccione accesos directos de la Aplicación, pulse el + botón y cambiar la aplicación de Correo el acceso directo asignado al elemento de menú en Respuesta a R. Vamos a cambiarlo para evitar conflictos a la hora de asignar R a el servicio a continuación:

enter image description here

  • Seleccione Servicios, desplácese hacia abajo para el servicio de que se haya agregado anteriormente y configurar el atajo de teclado R:

enter image description here

  • Abrir El Correo. Observe que la Respuesta de acceso directo ya no es R, pero R:

enter image description here

  • Observe también que hay un nuevo servicio, accesible con la tecla⌘R:

enter image description here

  • Ahora seleccione un mensaje en una carpeta, pulse la tecla⌘R, escriba su respuesta y enviar, en un par de segundos usted debería ver el mensaje enviado aparecen en la carpeta.

El guión tiene algunas limitaciones y efectos secundarios:

  • El servicio no puede decir cancelado y mensajes enviados aparte. Por lo tanto, si usted presiona R y, a continuación, cambiar su cuenta y cerrar la ventana, el servicio continuará la ejecución y verificación de la carpeta "Enviados" por la coincidencia de Id.

  • AppleScript no ofrece ningún medio de obtener una lista de respuestas a un mensaje. Mi solución es obtener el identificador del mensaje que se respondió y su búsqueda en los mensajes enviados.

  • El mensaje enviado no se puede mover mientras se descarga. AppleScript no devuelve ningún mensaje de error si ese es el caso, por lo que añade un retardo de 10 segundos. Un retardo de 5 segundos no era fiable en mis pruebas, adaptarlo a sus necesidades si es necesario.

  • Mientras que el servicio busca en la carpeta Enviados, Correo ralentiza.

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: