7 votos

Hacer que Safari cargue pestañas de fondo

Creo que este comportamiento es nuevo desde Safari 11, pero no estoy absolutamente seguro.

Que tienden a dejar de Safari abierto todo el tiempo, con varias páginas de fichas, cada una diferente de 'sujeto'.
El relanzamiento - si he estado de limpieza menos salados, galletas, etc, o incluso que rara ocasión se me reinicio - se utiliza para volver a cargar todas las fichas, ya sea visible o no.

Este comportamiento ha cambiado y ahora cada ficha voy a será en blanco y no carga, hasta que realmente cambiar a ella. Entiendo que la filosofía podría ser el ahorro de recursos, hasta que "probar" que las necesite, pero honestamente, si yo no tenía necesidad de ellos no se abre, en primer lugar.
De hecho, he desarrollado el hábito de rápidamente moviéndose a través de todas las pestañas después de su lanzamiento, así que estoy viendo sólo el retraso irritante de una vez.

Más irritación - la versión de carga después de 2 segundos de pausa es todavía la versión en caché, así que tienes que actualizar inmediatamente de todos modos:/

Así que me gustaría eliminar este comportamiento.

Quiero, si es posible, que cada ficha ya está cargado con el actual, no se almacena en caché, la versión de la página en el momento de Safari fue lanzado. Puedo manejar mi propio refrescante después de eso, solo quiero no tener que esperar a que el extra de 2 segundos para cada uno & cada ficha en el primer uso.

Tengo el Desarrollar Y Depurar los menús ya visible, en caso de que el 'fix' está ahí, pero, francamente, mi comprensión de los menús es sub-óptima. Creo con toda honestidad que he visibles a hacer que me sienta fresca, en lugar de porque estoy realmente sabe de lo que está ;)

Este es actualmente Safari 11.0.2 en El Capitan.

2voto

Elegant Coder Puntos 123

No estoy al tanto de cualquier forma alterar de Safari en el comportamiento por defecto, pero esta tarea puede ser automatizado con bastante facilidad, si usted tiene los medios para ejecutar un AppleScript.

Yo uso FastScripts y Teclado Maestro mí, para que yo pueda asignar globales o específicas de la aplicación de atajos de teclado para mi muchos de los scripts.

Este AppleScript se recarga cada pestaña en Safari en el frente de la ventana.

----------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2015/11/14 16:46
# Appl: Safari
# Task: Reload Every Tab in front window.
# Libs: ELb
# Osax: None
# Tags: @Applescript, @Safari, @Reload, @Tabs, @Front, @Window
----------------------------------------------------------------

try

   tell application "Safari"

      set tabList to tabs of front window

      repeat with theTab in tabList
         tell theTab to do JavaScript "location.reload(true)"
      end repeat

   end tell

on error e number n
   stdErr(e, n, true, true) of me
end try

----------------------------------------------------------------
--» HANDLERS
----------------------------------------------------------------
on stdErr(e, n, beepFlag, ddFlag)
   set e to e & return & return & "Num: " & n
   if beepFlag = true then
      beep
   end if
   if ddFlag = true then
      if n ≠ -128 then
         try
            tell application (path to frontmost application as text) to set ddButton to button returned of ¬
               (display dialog e with title "ERROR!" buttons {"Copy Error Message", "Cancel", "OK"} ¬
                  default button "OK" giving up after 30)
            if ddButton = "Copy Error Message" then set the clipboard to e
         end try
      end if
   else
      return e
   end if
end stdErr
----------------------------------------------------------------

En mi sistema he dado un método abreviado de teclado de R, que es un buen recurso mnemotécnico para mí.

Es bastante fácil de alterar la secuencia de comandos para volver a cargar cada ficha en cada ventana.

----------------------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2011/08/09 20:57
# Appl: Safari
# Task: Reload Every Tab in Every Window.
# Libs: None
# Osax: None
# Tags: @Applescript, @Reload, @Tabs, @Every, @Window
----------------------------------------------------------------------------

tell application "Safari"

    set tabList to tabs of windows

    repeat with theWindow in tabList
        repeat with theTab in theWindow
            tell (theTab's contents)
                do JavaScript "location.reload(true)"
            end tell
        end repeat
    end repeat

end tell

----------------------------------------------------------------------------

Yo uso éste, por lo que rara vez no he dado un atajo de teclado y tengo que activar manualmente desde el FastScripts menú. (Esta es también una salvaguarda para que no me de golpear una tecla de acceso directo accidente y tener que esperar por cada ficha para volver a cargar.)

-ccs

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: