0 votos

¿Cómo puedo hacer un servicio de Automator ejecutar un Terminal y mostrar la salida?

Estoy usando Automator para ejecutar una secuencia de comandos de shell (Rar archivos seleccionados) como un "Servicio", por lo que me puede hacer clic derecho sobre la carpeta y seleccione el servicio. Funciona bien, pero he añadido detallado y pruebas (para ver el progreso y los resultados de la prueba) así que tengo que ver la salida de la Terminal de la ventana para asegurarse de que el archivo está bien. Es allí una manera de ver el resultado en tiempo real? o tomar un paso extra eco de los resultados?

aquí está la secuencia de comandos que funciona en automator, pero la salida está en silencio.

on run {input, parameters}
set nbFiles to count input

if nbFiles = 0 then
    display dialog "No files selected!" buttons {"OK"} default button 1
    return
end if

tell application "Finder"

    set archiveDir to (container of (item 1 of input) as string)
    if nbFiles = 1 then
        set archiveName to (name of (item 1 of input) as string)
    else
        set archiveName to "archive"
    end if

    if exists file (archiveDir & archiveName & ".rar") then
        set i to 2
        repeat while exists file (archiveDir & archiveName & "-" & i & ".rar")
            set i to i + 1
        end repeat
        set archiveName to archiveName & "-" & i
    end if

    set archiveDir to quoted form of POSIX path of archiveDir
    set archiveName to quoted form of (archiveName & ".rar")

    set listFiles to " "
    repeat with i in input
        set listFiles to listFiles & quoted form of ("." & POSIX path of (name of i as string)) & " "
    end repeat

end tell

do shell script "cd " & archiveDir & "; rar a -ol[a] -mt8 -m5- -y -s -m4 -t " & archiveName & listFiles

return input
end run

GRACIAS!!

1voto

user3439894 Puntos 5883

Cambiar la siguiente línea de código:

do shell script "cd " & archiveDir & "; rar a -ol[a] -mt8 -m5- -y -s -m4 -t " & archiveName & listFiles

Para:

tell application "Terminal"
    do script "cd " & archiveDir & "; rar a -ol[a] -mt8 -m5- -y -s -m4 -t " & archiveName & listFiles   
end tell

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by:

X