7 votos

Es posible reiniciar una aplicación usando AppleScript?

Quiero reiniciar Safari y abrirlo con algunas fichas que se le especifiquen.

8voto

Nick Berardi Puntos 31361

Un método alternativo es usar Safari integrado en "volver a Abrir Todas las Windows de la Última Sesión" de la característica:

tell application "Safari"
    quit
end tell

delay 2 -- Wait for Safari to close

tell application "Safari" to activate
tell application "System Events"
    tell process "Safari"
        click menu item "Reopen All Windows From Last Session" of menu "History" of menu bar 1
    end tell
end tell

3voto

aku Puntos 54867

Para guardar ventanas/pestañas de una sesión y volver a abrir ellos, no hay una solución aquí: http://hints.macworld.com/article.php?story=20030913153245341 Asegúrese de leer los comentarios, al parecer, ha habido varias actualizaciones para las secuencias de comandos. Edit: Acabo de uso Chealion la respuesta, mucho más suave.

Si usted sólo desea abrir un determinado conjunto de fichas, usted puede utilizar esta secuencia de comandos:

tell application "Safari"
    set urllist to {"http://google.com", "http://stackoverflow.com", "http://apple.stackexchange.com"}

    repeat with i from 1 to number of items in urllist
        set URL of document 1 to item i of urllist
        if i is less than number of items in urllist then
            my new_tab()
        end if
    end repeat
end tell

on new_tab()
    tell application "Safari" to activate
    tell application "System Events"
        tell process "Safari"
            click menu item "New Tab" of menu "File" of menu bar 1
        end tell
    end tell
end new_tab

Sólo la lista de las direcciones de las páginas que desea abrir entre el {} en la línea 2. Cada una de las direcciones dentro de "" y separados por ,.

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: