0 votos

Menú contextual en AppleScript

Buenos días.

Me encuentro en una situación sin saber cómo hacer para poder invocar y hacer uso del menú contextual.

Me sería de gran utilidad un sencillo ejemplo del código de AppleScript para poder usar el menú contextual (el que aparece pulsando el botón derecho del ratón), por ejemplo en el Finder.

Agradecimientos de antemano.

Salud

1voto

Michael Grant Puntos 10
tell application "System Events"
    tell application process "Finder"
        set frontmost to true
        set ui to value of attribute "AXFocusedUIElement"
        tell application "Finder" to activate
        set a_class to class of ui
        if a_class is outline then
            tell ui
                try
                    perform action "AXShowMenu"
                    return
                on error
                    beep
                end try
            end tell
            return
        else if a_class is scroll area then
            tell outline 1 of ui
                set a_row to item 1 of (rows where it is selected)
                tell UI element 1 of a_row
                    try
                        perform action "AXShowMenu"
                    on error
                        beep
                    end try
                end tell
            end tell
        else if a_class is group then
            tell ui
                set an_item to item 1 of (UI elements where it is selected)
                tell an_item
                    try
                        perform action "AXShowMenu"
                    on error
                        beep
                    end try
                end tell
            end tell
        else if a_class is browser then
            tell scroll area 1 of ui
                set n_list to count scroll areas
                repeat with n from n_list to 1 by -1
                    tell list 1 of scroll area n
                        set selected_elements to (UI elements whose selected is true)
                        if length of selected_elements > 0 then
                            tell item 1 of selected_elements
                                try
                                    perform action "AXShowMenu"
                                on error
                                    beep
                                end try
                            end tell
                            exit repeat
                        end if
                    end tell
                end repeat
            end tell
        end if
    end tell
end tell

1 votos

Buenas noches, Michael. Muchas gracias por tu generosidad al compartir tu tiempo y conocimientos a fin de prestarme tu ayuda. :-) Salud.

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: