3 votos

En iTunes 12 en macOS, ¿cómo puedo restablecer el recuento de omisión de una canción?

Todo lo que puede encontrar en el internet parece referirse a una versión diferente de macOS/iTunes de las que me estoy quedando. Quiero restablecer el recuento de omisión de pistas sin restablecer sus aspectos el juego, así.

Estoy bien con AppleScript, si eso es lo que tiene que hacer, pero algo estaría bien :)

6voto

wch1zpink Puntos 11

Este siguiente AppleScript código me funciona con la última versión de macOS Mojave.

tell application "iTunes"
    tell its track "Insert Your Song Title"
        set its skipped count to 0 -- Enter Your Desired Number     
    end tell
end tell

El código siguiente se aborda el tema de varias canciones con el mismo nombre.

tell application "iTunes"
    set theTrack to "Insert Your Song Title"
    set tracksRef to a reference to (tracks whose name is theTrack)

    set trackCount to count of tracksRef

    if trackCount is greater than 1 then
        set theArtists to artist of tracksRef
        set chooseArtist to (choose from list theArtists with title "Choose The Artist" with prompt ¬
            "Choose The Artist" OK button name "OK" cancel button name "Cancel") as text
        tell (every track whose name is theTrack and artist is chooseArtist)
            set skipped count to 0 -- Enter Your Desired Number     
        end tell
    else
        tell its track theTrack
            set its skipped count to 0 -- Enter Your Desired Number     
        end tell
    end if
end tell

Este código siguiente debe trabajar si desea restablecer omitido conteo de cada pista.

tell application "iTunes"
    set allTracks to every track
    repeat with i from 1 to count of allTracks
        set thisItem to item i of allTracks
        tell thisItem
            try
                set its skipped count to 0 -- Enter Your Desired Number     
            end try
        end tell
    end repeat
end tell

4voto

user3439894 Puntos 5883

Me di cuenta en el comentario a tu OP donde usted contestó "temas Seleccionados" para dwightk comentario de preguntas "Todas las pistas? O pistas seleccionadas?" Así que...

Para restablecer el Salta recuento de todas las pistas seleccionadas, utilice simplemente:

tell application "iTunes" to set skipped count of selection to 0

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: