2 votos

¿Hay alguna manera de cambiar la posición del mac dock con un atajo de teclado?

Creo que no hay atajos para que. Pero supongo que usted podría hacer uno usando AppleScript o de otros programas de automatización.

He encontrado este post de 2012 preguntando la misma pregunta. Traté de hacer el guión previsto en los comentarios, pero no podía hacer el trabajo.

No estoy seguro de que si no está funcionando debido a que Apple secuencias de comandos son diferentes ahora, o porque el guión de por sí no funciona o porque hay pasos que me estoy saltando.

Cuando intento guardar el script que dice

"Espera "dado", "con", "sin", otro nombre de parámetro, etc. pero se encontró identificador."

Alguna idea?

3voto

wch1zpink Puntos 11

Este código AppleScript funciona para mí con la última versión de macOS Mojave.

 tell application "System Events" to tell dock preferences
    if screen edge is bottom then
        set screen edge to left
    else if screen edge is left then
        set screen edge to bottom
    end if
end tell
 

En Automator, cree un nuevo Servicio o Acción rápida y agregue una acción de ejecución de AppleScript a ese flujo de trabajo, agregando el código de AppleScript anterior. Luego, en Preferencias del sistema, puede crear un método abreviado de teclado para ese nuevo servicio.

1voto

user3439894 Puntos 5883

La razón de que usted obtenga el Error de Sintaxis:

Espera que "dado", "con", "sin", otro nombre de parámetro, etc. pero se encontró identificador.

De:

defaults write com.apple.Dock orientation -string left;killall Dock

En el Editor de secuencias de Comandos es porque no es AppleScript código!

Es un compuesto de comandos para ejecutar en el Terminal; sin embargo, se puede ejecutar en AppleScript mediante el uso de la do shell script comando:

do shell script "defaults write com.apple.Dock orientation -string left;killall Dock"

Dicho esto, yo prefiero que no lo uso porque el resultado de killall Dock con mostrar todas las ventanas ocultas y puede ser muy perjudicial, y desordenado.

Una alternativa es el uso de secuencias de comandos de interfaz de usuario1 con las Preferencias del Sistema, y esto puede ser hecho de una manera menos perturbadora, a continuación, killall Dock. 1tenga en cuenta que el uso de secuencias de comandos de interfaz de usuario puede requerir la accesibilidad de los privilegios de ser concedido.

El siguiente ejemplo de AppleScript código cambiará la posición del Muelle entre la parte Inferior y a la Izquierda lado de la pantalla:

Esto fue probado en el Editor de secuencias de Comandos y funciona bajo macOS Sierra Alta.

if running of application "System Preferences" then
    try
        tell application "System Preferences" to quit
    on error
        do shell script "killall 'System Preferences'"
    end try
end if

repeat while running of application "System Preferences" is true
    delay 0.01
end repeat

tell application "System Preferences" to ¬
    reveal anchor "Main" of pane id "com.apple.preference.dock"

tell application "System Events" to tell application process "System Preferences"
    repeat while not (exists (window "Dock"))
        delay 0.1
    end repeat
    tell radio group 1 of window "Dock"
        if value of radio button "Bottom" is 1 then
            click radio button "Left"
        else if value of radio button "Left" is 1 then
            click radio button "Bottom"
        end if
    end tell
end tell

quit application "System Preferences"

Este ejemplo de AppleScript código puede ser utilizado en un Automator Servicio (de Acción Rápida en macOS Mojave), utilizando un Ejecutar AppleScript acción, y asignar un método abreviado de teclado en: Preferencias del Sistema > Teclado > accesos directos > Servicios


Nota: El ejemplo de AppleScript código es sólo eso y no contiene ningún error de manipulación como puede ser apropiado. La responsabilidad recae sobre el usuario para agregar cualquier error de manipulación como puede ser apropiado, necesitaba o quería. Echa un vistazo al tratar de instrucción y de error de instrucción en la Guía de Lenguaje de AppleScript. Véase también el Trabajo con los Errores. Además, el uso de la demora de comandos puede ser necesaria entre los eventos donde apropiada, por ejemplo delay 0.5, con el valor de la demora establecido de forma adecuada.

AppleAyuda.com

AppleAyuda es una comunidad de usuarios de los productos de Apple en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros usuarios, hacer tus propias preguntas o resolver las de los demás.

Powered by: